@echo off
					
REM **************************************************************************
REM Starts ProEWildFire 3.0 and creates folders if necessary
REM **************************************************************************


REM **** creates local directories *******************************************
if not exist C:\ptc\start_wf3 mkdir C:\ptc\start_wf3
if not exist C:\ptc\start_wf3\pdm_cache mkdir C:\ptc\start_wf3\pdm_cache
if not exist C:\ptc\trail_dir mkdir C:\ptc\trail_dir
if not exist C:\ptc\pdf mkdir C:\ptc\pdf
if not exist C:\Temp mkdir C:\Temp


REM ****  set LOAD POINT directory  **************************************************
if exist P:\proewildfire3 set proe_load=P:\proewildfire3

REM **** set work dir ********************************************************
if exist C:\ptc\start_wf3 set work_dir=C:\ptc\start_wf3

REM **** set pro dir *********************************************************
if exist P:\prolib set pro_dir=P:\prolib

REM **** set graphiclib dir *********************************************************
if exist P:\graphiclib set graphiclib_dir=P:\graphiclib

REM **** modelcheck  dir *********************************************************
set mcdir=%pro_dir%\mc_config

REM **** PDMLink work folder **********************************************
set PTC_WF_ROOT=%work_dir%\pdm_cache

REM **** set path *********************************************************
set path=%path%;%proe_load%\bin

REM ****  SWITCHING TO USER WORKING DIR  ******************************************
cd /D %work_dir%

REM **** clean workdir *******************************************************
call %pro_dir%\text_wf3\clean.bat

REM **** copy files to local computer ****************************************
if not exist %work_dir%\config.pro copy %pro_dir%\text_wf3\config_local.pro %work_dir%\config.pro

REM **** start ProE *****************************************************
call %proe_load%\bin\proe_borrow.bat
